Merge branch 'main' into jetbrains

Add agent_name parameter to URLs for workspaces with
multiple agents. Updated tests to ensure correct URL
generation, with and without agent_name specified.

.icons/jetbrains.svg

@@ -0,0 +1 @@
+<svg fill="none" height="64" viewBox="0 0 64 64" width="64" xmlns="http://www.w3.org/2000/svg" xmlns:xlink="http://www.w3.org/1999/xlink"><linearGradient id="a" gradientUnits="userSpaceOnUse" x1=".850001" x2="62.62" y1="62.72" y2="1.81"><stop offset="0" stop-color="#ff9419"/><stop offset=".43" stop-color="#ff021d"/><stop offset=".99" stop-color="#e600ff"/></linearGradient><clipPath id="b"><path d="m0 0h64v64h-64z"/></clipPath><g clip-path="url(#b)"><path d="m20.34 3.66-16.68 16.68c-2.34 2.34-3.66 5.52-3.66 8.84v29.82c0 2.76 2.24 5 5 5h29.82c3.32 0 6.49-1.32 8.84-3.66l16.68-16.68c2.34-2.34 3.66-5.52 3.66-8.84v-29.82c0-2.76-2.24-5-5-5h-29.82c-3.32 0-6.49 1.32-8.84 3.66z" fill="url(#a)"/><path d="m48 16h-40v40h40z" fill="#000"/><path d="m30 47h-17v4h17z" fill="#fff"/></g></svg>

registry/coder/modules/filebrowser/main.test.ts

@@ -84,7 +84,6 @@ describe("filebrowser", async () => {
       "sh",
       "apk add bash",
     );
-
   }, 15000);
 
   it("runs with subdomain=false", async () => {

registry/coder/modules/jetbrains/README.md

@@ -0,0 +1,148 @@
+---
+display_name: JetBrains Toolbox
+description: Add JetBrains IDE integrations to your Coder workspaces with configurable options.
+icon: ../../../../.icons/jetbrains.svg
+maintainer_github: coder
+verified: true
+tags: [ide, jetbrains, parameter]
+---
+
+# JetBrains IDEs
+
+This module adds JetBrains IDE buttons to launch IDEs directly from the dashboard by integrating with the JetBrains Toolbox.
+
+```tf
+module "jetbrains" {
+  count    = data.coder_workspace.me.start_count
+  source   = "registry.coder.com/coder/jetbrains/coder"
+  version  = "1.0.0"
+  agent_id = coder_agent.example.id
+  folder   = "/home/coder/project"
+}
+```
+
+![JetBrains IDEs list](../../.images/jetbrains-dropdown.png)
+
+> [!IMPORTANT]
+> This module requires Coder version 2.24+ and [JetBrains Toolbox](https://www.jetbrains.com/toolbox-app/) version 2.7 or higher.
+
+> [!WARNING]
+> JetBrains recommends a minimum of 4 CPU cores and 8GB of RAM.
+> Consult the [JetBrains documentation](https://www.jetbrains.com/help/idea/prerequisites.html#min_requirements) to confirm other system requirements.
+
+## Examples
+
+### Pre-configured Mode (Direct App Creation)
+
+When `default` contains IDE codes, those IDEs are created directly without user selection:
+
+```tf
+module "jetbrains" {
+  count    = data.coder_workspace.me.start_count
+  source   = "registry.coder.com/coder/jetbrains/coder"
+  version  = "1.0.0"
+  agent_id = coder_agent.example.id
+  folder   = "/home/coder/project"
+  default  = ["PY", "IU"] # Pre-configure GoLand and IntelliJ IDEA
+}
+```
+
+### User Choice with Limited Options
+
+```tf
+module "jetbrains" {
+  count    = data.coder_workspace.me.start_count
+  source   = "registry.coder.com/coder/jetbrains/coder"
+  version  = "1.0.0"
+  agent_id = coder_agent.example.id
+  folder   = "/home/coder/project"
+  # Show parameter with limited options
+  options = ["IU", "PY"] # Only these IDEs are available for selection
+}
+```
+
+### Early Access Preview (EAP) Versions
+
+```tf
+module "jetbrains" {
+  count         = data.coder_workspace.me.start_count
+  source        = "registry.coder.com/coder/jetbrains/coder"
+  version       = "1.0.0"
+  agent_id      = coder_agent.example.id
+  folder        = "/home/coder/project"
+  default       = ["IU", "PY"]
+  channel       = "eap"    # Use Early Access Preview versions
+  major_version = "2025.2" # Specific major version
+}
+```
+
+### Custom IDE Configuration
+
+```tf
+module "jetbrains" {
+  count    = data.coder_workspace.me.start_count
+  source   = "registry.coder.com/coder/jetbrains/coder"
+  version  = "1.0.0"
+  agent_id = coder_agent.example.id
+  folder   = "/workspace/project"
+
+  # Custom IDE metadata (display names and icons)
+  ide_config = {
+    "IU" = {
+      name  = "IntelliJ IDEA"
+      icon  = "/custom/icons/intellij.svg"
+      build = "251.26927.53"
+    }
+    "PY" = {
+      name  = "PyCharm"
+      icon  = "/custom/icons/pycharm.svg"
+      build = "251.23774.211"
+    }
+  }
+}
+```
+
+### Single IDE for Specific Use Case
+
+```tf
+module "jetbrains_pycharm" {
+  count    = data.coder_workspace.me.start_count
+  source   = "registry.coder.com/coder/jetbrains/coder"
+  version  = "1.0.0"
+  agent_id = coder_agent.example.id
+  folder   = "/workspace/project"
+
+  default = ["PY"] # Only PyCharm
+
+  # Specific version for consistency
+  major_version = "2025.1"
+  channel       = "release"
+}
+```
+
+## Behavior
+
+### Parameter vs Direct Apps
+
+- **`default = []` (empty)**: Creates a `coder_parameter` allowing users to select IDEs from `options`
+- **`default` with values**: Skips parameter and directly creates `coder_app` resources for the specified IDEs
+
+### Version Resolution
+
+- Build numbers are fetched from the JetBrains API for the latest compatible versions when internet access is available
+- If the API is unreachable (air-gapped environments), the module automatically falls back to build numbers from `ide_config`
+- `major_version` and `channel` control which API endpoint is queried (when API access is available)
+
+## Supported IDEs
+
+All JetBrains IDEs with remote development capabilities:
+
+- [CLion (`CL`)](https://www.jetbrains.com/clion/)
+- [GoLand (`GO`)](https://www.jetbrains.com/go/)
+- [IntelliJ IDEA Ultimate (`IU`)](https://www.jetbrains.com/idea/)
+- [PhpStorm (`PS`)](https://www.jetbrains.com/phpstorm/)
+- [PyCharm Professional (`PY`)](https://www.jetbrains.com/pycharm/)
+- [Rider (`RD`)](https://www.jetbrains.com/rider/)
+- [RubyMine (`RM`)](https://www.jetbrains.com/ruby/)
+- [RustRover (`RR`)](https://www.jetbrains.com/rust/)
+- [WebStorm (`WS`)](https://www.jetbrains.com/webstorm/)

registry/coder/modules/jetbrains/main.tf

@@ -0,0 +1,250 @@
+terraform {
+  required_version = ">= 1.0"
+
+  required_providers {
+    coder = {
+      source  = "coder/coder"
+      version = ">= 2.5"
+    }
+    http = {
+      source  = "hashicorp/http"
+      version = ">= 3.0"
+    }
+  }
+}
+
+variable "agent_id" {
+  type        = string
+  description = "The resource ID of a Coder agent."
+}
+
+variable "agent_name" {
+  type        = string
+  description = "The name of a Coder agent. Needed for workspaces with multiple agents."
+  default     = null
+}
+
+variable "folder" {
+  type        = string
+  description = "The directory to open in the IDE. e.g. /home/coder/project"
+  validation {
+    condition     = can(regex("^(?:/[^/]+)+/?$", var.folder))
+    error_message = "The folder must be a full path and must not start with a ~."
+  }
+}
+
+variable "default" {
+  default     = []
+  type        = set(string)
+  description = <<-EOT
+    The default IDE selection. Removes the selection from the UI. e.g. ["CL", "GO", "IU"]
+  EOT
+}
+
+variable "group" {
+  type        = string
+  description = "The name of a group that this app belongs to."
+  default     = null
+}
+
+variable "coder_app_order" {
+  type        = number
+  description = "The order determines the position of app in the UI presentation. The lowest order is shown first and apps with equal order are sorted by name (ascending order)."
+  default     = null
+}
+
+variable "coder_parameter_order" {
+  type        = number
+  description = "The order determines the position of a template parameter in the UI/CLI presentation. The lowest order is shown first and parameters with equal order are sorted by name (ascending order)."
+  default     = null
+}
+
+variable "major_version" {
+  type        = string
+  description = "The major version of the IDE. i.e. 2025.1"
+  default     = "latest"
+  validation {
+    condition     = can(regex("^[0-9]{4}\\.[0-2]{1}$", var.major_version)) || var.major_version == "latest"
+    error_message = "The major_version must be a valid version number. i.e. 2025.1 or latest"
+  }
+}
+
+variable "channel" {
+  type        = string
+  description = "JetBrains IDE release channel. Valid values are release and eap."
+  default     = "release"
+  validation {
+    condition     = can(regex("^(release|eap)$", var.channel))
+    error_message = "The channel must be either release or eap."
+  }
+}
+
+variable "options" {
+  type        = set(string)
+  description = "The list of IDE product codes."
+  default     = ["CL", "GO", "IU", "PS", "PY", "RD", "RM", "RR", "WS"]
+  validation {
+    condition = (
+      alltrue([
+        for code in var.options : contains(["CL", "GO", "IU", "PS", "PY", "RD", "RM", "RR", "WS"], code)
+      ])
+    )
+    error_message = "The options must be a set of valid product codes. Valid product codes are ${join(",", ["CL", "GO", "IU", "PS", "PY", "RD", "RM", "RR", "WS"])}."
+  }
+  # check if the set is empty
+  validation {
+    condition     = length(var.options) > 0
+    error_message = "The options must not be empty."
+  }
+}
+
+variable "releases_base_link" {
+  type        = string
+  description = "URL of the JetBrains releases base link."
+  default     = "https://data.services.jetbrains.com"
+  validation {
+    condition     = can(regex("^https?://.+$", var.releases_base_link))
+    error_message = "The releases_base_link must be a valid HTTP/S address."
+  }
+}
+
+variable "download_base_link" {
+  type        = string
+  description = "URL of the JetBrains download base link."
+  default     = "https://download.jetbrains.com"
+  validation {
+    condition     = can(regex("^https?://.+$", var.download_base_link))
+    error_message = "The download_base_link must be a valid HTTP/S address."
+  }
+}
+
+data "http" "jetbrains_ide_versions" {
+  for_each = length(var.default) == 0 ? var.options : var.default
+  url      = "${var.releases_base_link}/products/releases?code=${each.key}&type=${var.channel}&latest=true${var.major_version == "latest" ? "" : "&major_version=${var.major_version}"}"
+}
+
+variable "ide_config" {
+  description = <<-EOT
+    A map of JetBrains IDE configurations.
+    The key is the product code and the value is an object with the following properties:
+    - name: The name of the IDE.
+    - icon: The icon of the IDE.
+    - build: The build number of the IDE.
+    Example:
+    {
+      "CL" = { name = "CLion", icon = "/icon/clion.svg", build = "251.26927.39" },
+      "GO" = { name = "GoLand", icon = "/icon/goland.svg", build = "251.26927.50" },
+      "IU" = { name = "IntelliJ IDEA", icon = "/icon/intellij.svg", build = "251.26927.53" },
+    }
+  EOT
+  type = map(object({
+    name  = string
+    icon  = string
+    build = string
+  }))
+  default = {
+    "CL" = { name = "CLion", icon = "/icon/clion.svg", build = "251.26927.39" },
+    "GO" = { name = "GoLand", icon = "/icon/goland.svg", build = "251.26927.50" },
+    "IU" = { name = "IntelliJ IDEA", icon = "/icon/intellij.svg", build = "251.26927.53" },
+    "PS" = { name = "PhpStorm", icon = "/icon/phpstorm.svg", build = "251.26927.60" },
+    "PY" = { name = "PyCharm", icon = "/icon/pycharm.svg", build = "251.26927.74" },
+    "RD" = { name = "Rider", icon = "/icon/rider.svg", build = "251.26927.67" },
+    "RM" = { name = "RubyMine", icon = "/icon/rubymine.svg", build = "251.26927.47" },
+    "RR" = { name = "RustRover", icon = "/icon/rustrover.svg", build = "251.26927.79" },
+    "WS" = { name = "WebStorm", icon = "/icon/webstorm.svg", build = "251.26927.40" }
+  }
+  validation {
+    condition     = length(var.ide_config) > 0
+    error_message = "The ide_config must not be empty."
+  }
+  # ide_config must be a superset of var.. options
+  validation {
+    condition = alltrue([
+      for code in var.options : contains(keys(var.ide_config), code)
+    ])
+    error_message = "The ide_config must be a superset of var.options."
+  }
+}
+
+locals {
+  # Parse HTTP responses once with error handling for air-gapped environments
+  parsed_responses = {
+    for code in length(var.default) == 0 ? var.options : var.default : code => try(
+      jsondecode(data.http.jetbrains_ide_versions[code].response_body),
+      {} # Return empty object if API call fails
+    )
+  }
+
+  # Dynamically generate IDE configurations based on options with fallback to ide_config
+  options_metadata = {
+    for code in length(var.default) == 0 ? var.options : var.default : code => {
+      icon       = var.ide_config[code].icon
+      name       = var.ide_config[code].name
+      identifier = code
+      key        = code
+
+      # Use API build number if available, otherwise fall back to ide_config build number
+      build = length(keys(local.parsed_responses[code])) > 0 ? (
+        local.parsed_responses[code][keys(local.parsed_responses[code])[0]][0].build
+      ) : var.ide_config[code].build
+
+      # Store API data for potential future use (only if API is available)
+      json_data    = length(keys(local.parsed_responses[code])) > 0 ? local.parsed_responses[code][keys(local.parsed_responses[code])[0]][0] : null
+      response_key = length(keys(local.parsed_responses[code])) > 0 ? keys(local.parsed_responses[code])[0] : null
+    }
+  }
+
+  # Convert the parameter value to a set for for_each
+  selected_ides = length(var.default) == 0 ? toset(jsondecode(coalesce(data.coder_parameter.jetbrains_ides[0].value, "[]"))) : toset(var.default)
+}
+
+data "coder_parameter" "jetbrains_ides" {
+  count        = length(var.default) == 0 ? 1 : 0
+  type         = "list(string)"
+  name         = "jetbrains_ides"
+  display_name = "JetBrains IDEs"
+  icon         = "/icon/jetbrains-toolbox.svg"
+  mutable      = true
+  default      = jsonencode([])
+  order        = var.coder_parameter_order
+  form_type    = "multi-select" # requires Coder version 2.24+
+
+  dynamic "option" {
+    for_each = var.options
+    content {
+      icon  = var.ide_config[option.value].icon
+      name  = var.ide_config[option.value].name
+      value = option.value
+    }
+  }
+}
+
+data "coder_workspace" "me" {}
+data "coder_workspace_owner" "me" {}
+
+resource "coder_app" "jetbrains" {
+  for_each     = local.selected_ides
+  agent_id     = var.agent_id
+  slug         = "jetbrains-${lower(each.key)}"
+  display_name = local.options_metadata[each.key].name
+  icon         = local.options_metadata[each.key].icon
+  external     = true
+  order        = var.coder_app_order
+  url = join("", [
+    "jetbrains://gateway/coder?&workspace=", # requires 2.6.3+ version of Toolbox
+    data.coder_workspace.me.name,
+    "&owner=",
+    data.coder_workspace_owner.me.name,
+    "&folder=",
+    var.folder,
+    "&url=",
+    data.coder_workspace.me.access_url,
+    "&token=",
+    "$SESSION_TOKEN",
+    "&ide_product_code=",
+    each.key,
+    "&ide_build_number=",
+    local.options_metadata[each.key].build,
+    var.agent_name != null ? "&agent_name=${var.agent_name}" : "",
+  ])
+}

registry/coder/modules/zed/main.test.ts

@@ -16,9 +16,7 @@ describe("zed", async () => {
     const state = await runTerraformApply(import.meta.dir, {
       agent_id: "foo",
     });
-    expect(state.outputs.zed_url.value).toBe(
-      "zed://ssh/default.coder",
-    );
+    expect(state.outputs.zed_url.value).toBe("zed://ssh/default.coder");
 
     const coder_app = state.resources.find(
       (res) => res.type === "coder_app" && res.name === "zed",
@@ -34,9 +32,7 @@ describe("zed", async () => {
       agent_id: "foo",
       folder: "/foo/bar",
     });
-    expect(state.outputs.zed_url.value).toBe(
-      "zed://ssh/default.coder/foo/bar",
-    );
+    expect(state.outputs.zed_url.value).toBe("zed://ssh/default.coder/foo/bar");
   });
 
   it("expect order to be set", async () => {